home *** CD-ROM | disk | FTP | other *** search
/ Mac Magazin/MacEasy 32 / Mac Magazin and MacEasy Magazine CD - Issue 32.iso / Grafik & Text / OzTeX3.0 / Metafont / Inputs / ec / exrdigit.mf < prev    next >
Text File  |  1997-03-16  |  15KB  |  338 lines
  1. % exrdigit.mf
  2. %
  3. % (c) Copyright 1995, 1996, 1997 J"org Knappen
  4. % (c) Copyright 1990, 1992 Norbert Schwarz
  5. %
  6. % This file is part of ecfonts version 1.0
  7. %
  8. % Please read the files 00readme.txt, 00inst.txt, 00error.txt, and
  9. % copyrite.txt for further information
  10. %
  11. % You find some documentation in ecdoc.tex (needs LaTeX2e)
  12. %
  13. % Content:
  14. %
  15. %  numerals 0 .. 9
  16. %
  17.  
  18. version_check(1,0);  % |version_check| was introduced in dc1.3
  19.  
  20. % All digits have the same height, width, depth, and italic correction.
  21.  
  22. font_digit_width 9u#;
  23.  
  24. ecchar "The numeral 0";
  25. beginchar("0",9u#,fig_height#,0);
  26. italcorr fig_height#*slant-.5u#;
  27. adjust_fit(0,0);
  28. penpos1(vair,90); penpos3(vair,-90); penpos2(curve,180); penpos4(curve,0);
  29. if not monospace: interim superness:=sqrt(more_super*hein_super); fi
  30. x2r=hround max(.7u,1.45u-.5curve); x4r=w-x2r; x1=x3=.5w;
  31. y1r=h+o; y3r=-o; y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  32. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  33.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  34. penlabels(1,2,3,4); endchar;
  35.  
  36. ecchar "The numeral 1";
  37. beginchar("1",9u#,fig_height#,0);
  38. italcorr fig_height#*slant-.5u#;
  39. adjust_fit(0,0);
  40. numeric light_stem; light_stem=hround .4[stem',cap_stem'];
  41. pickup tiny.nib;
  42. pos1(light_stem,0); pos2(light_stem,0);
  43. lft x1l=lft x2l=hround(.5(w+.5u)-.5cap_stem'); top y1=h+o; bot y2=0;
  44. filldraw stroke z1e--z2e;  % stem
  45. if not serifs: save slab; slab=bar; fi
  46. if one_serif: dish_serif(2,1,a,1/3,min(2.25u,lft x2l-1.5u),
  47.   b,1/3,min(2.25u,w-1.25u-rt x2r)); fi % serif
  48. pickup crisp.nib; pos3(slab,-90); pos4(bar,-90);
  49. top y3l=h+o; top y4l=if monospace: .8 else: .9 fi\\ h+o;
  50. lft x4=max(1.25u,tiny.lft x1l-2.35u);
  51. tiny.rt x1r=lft x3+.25[tiny,hair];
  52. erase fill z3l{x4l-x3l,3(y4l-y3l)}...z4l{left}
  53.  --(x4l,h+o+1)--(x3l,h+o+1)--cycle; % erase excess at top
  54. filldraw stroke z3e{x4e-x3e,3(y4e-y3e)}..z4e{left};  % point
  55. penlabels(1,2,3,4); endchar;
  56.  
  57. ecchar "The numeral 2";
  58. beginchar("2",9u#,fig_height#,0);
  59. italcorr fig_height#*slant-.5u#;
  60. adjust_fit(0,0);
  61. numeric arm_thickness, hair_vair; hair_vair=.25[vair,hair];
  62. arm_thickness=Vround(if hefty:slab+2stem_corr else:.4[stem,cap_stem] fi);
  63. pickup crisp.nib; pos7(arm_thickness,-90); pos8(hair,0);
  64. bot y7r=0; lft x7=hround .9u; rt x8r=hround(w-.9u); y8=good.y(y7l+beak/2)+eps;
  65. arm(7,8,a,.3beak_darkness,beak_jut);  % arm and beak
  66. pickup fine.nib; pos2(slab,90); pos3(.4[curve,cap_curve],0);
  67. top y2r=h+o; x2=.5(w-.5u); rt x3r=hround(w-.9u); y3+.5vair=.75h;
  68. if serifs: numeric bulb_diam; bulb_diam=hround(flare+2/3(cap_stem-stem));
  69.  pos0(bulb_diam,180); pos1(cap_hair,180);
  70.  lft x1r=hround .9u; y1-.5bulb_diam=2/3h;
  71.  (x,y2l)=whatever[z1l,z2r]; x2l:=x; bulb(2,1,0);  % bulb and arc
  72. else: x2l:=x2l-.25u; pos1(flare,angle(-9u,h));
  73.  lft x1r=hround .75u; bot y1l=vround .7h; y1r:=good.y y1r+eps; x1l:=good.x x1l;
  74.  filldraw stroke term.e(2,1,left,.9,4); fi  % terminal and arc
  75. pos4(.25[hair_vair,cap_stem],0);
  76. pos5(hair_vair,0); pos6(hair_vair,0);
  77. y5=arm_thickness; y4=.3[y5,y3]; top y6=min(y5,slab,top y7l);
  78. lft x6l=crisp.lft x7; z4l=whatever[z6l,(x3l,bot .58h)]; z5l=whatever[z6l,z4l];
  79. erase fill z4l--z6l--lft z6l--(lft x6l,y4l)--cycle;  % erase excess at left
  80. filldraw stroke z2e{right}..tension atleast .9 and atleast 1
  81.  ..z3e{down}.. z4e---z5e--z6e;  % stroke
  82. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  83.  
  84. ecchar "The numeral 3";
  85. beginchar("3",9u#,fig_height#,0);
  86. italcorr fig_height#*slant-.5u#;
  87. adjust_fit(0,0);
  88. numeric top_thickness,mid_thickness,bot_thickness;
  89. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  90. mid_thickness=max(fine.breadth,vround 2/3vair);
  91. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  92. pickup fine.nib; pos2(top_thickness,90); top y2r=h+o;
  93. pos3(max(fine.breadth,.6[curve,cap_curve]-stem_corr),0);
  94. rt x3r=hround(w-1.25u);
  95. pos4(vair,-90); pos5(vair,-90);
  96. pos6(mid_thickness,90); x2=x6=x8=.5[1.5u,x7];
  97. pos7(cap_curve,0); rt x7r=hround(w-.75u); lft x5=min(hround 3u,lft x6)-eps;
  98. pos8(bot_thickness,-90); bot y8r=-o;
  99. y3=.6[top y4l,bot y2l]; y7=.5[bot y6l,top y8l];
  100. top y5l=vround(.54h+.5vair); y5r=y6l;
  101. x4=1/3[x5,x3l]; z4=z5+whatever*(150u,h);
  102. filldraw stroke pulled_super_arc.e(2,3)(.5superpull)
  103.  & z3e{down}...z4e---z5e;  % upper bowl
  104. filldraw z5r--z6l--z6r--z5l---cycle;  % middle tip
  105. filldraw stroke pulled_super_arc.e(6,7)(.5superpull)
  106.  & pulled_super_arc.e(7,8)(.5superpull);  % lower bowl
  107. if serifs: numeric bulb_diam[];
  108.  bulb_diam1=flare+.5(cap_stem-stem); bulb_diam2=flare+cap_stem-stem;
  109.  pos0(bulb_diam1,180); pos1(hair,180);
  110.  lft x0r=hround 1.25u; y0=min(.9h-.5bulb_diam1,.75h+.5bulb_diam1);
  111.  bulb(2,1,0);  % upper bulb
  112.  pos10(bulb_diam2,-180); pos9(cap_hair,-180);
  113.  lft x10r=hround .75u; y10=max(.1h+.5bulb_diam2,.3h-.5bulb_diam2);
  114.  bulb(8,9,10);  % lower bulb
  115. else: pos1(.5[vair,flare],angle(-8u,h));
  116.  lft x1r=hround u; bot y1l=vround .75h+o;
  117.  y1r:=good.y y1r+eps; x1l:=good.x x1l;
  118.  pos9(bot_thickness,angle(-2u,-h));
  119.  lft x9r=hround .75u; top y9l=vround .25h-o;
  120.  y9r:=good.y y9r-eps; x9l:=good.x x9l;
  121.  filldraw stroke term.e(2,1,left,1,4);  % upper terminal
  122.  filldraw stroke term.e(8,9,left,1,4); fi  % lower terminal
  123. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  124.  
  125. ecchar "The numeral 4";
  126. beginchar("4",9u#,fig_height#,0);
  127. italcorr fig_height#*slant-.5u#;
  128. adjust_fit(0,0);
  129. numeric light_stem, light_stem', diag_stem, alpha, cut; cut=.75notch_cut;
  130. light_stem=hround .4[fudged.stem,fudged.cap_stem];
  131. light_stem'=hround max(tiny.breadth,light_stem-2stem_corr);
  132. diag_stem=max(tiny.breadth,.4[vair,fudged.hair]);
  133. pickup crisp.nib; pos5(cap_bar,90); pos6(cap_bar,90);
  134. lft x5=hround .5u; rt x6=hround(w-.5u);
  135. top y5r=vround(if serifs: 5/18[slab,h-light_stem]+1
  136.  else:.35(h-light_stem) fi+.5cap_bar);
  137. z4l=top lft z5r; y2=y2'=y5=y6; x1r=x2r=hround(w-3u+.5light_stem);
  138. penpos1(light_stem',0); penpos2(light_stem',0); y1=y3=h+apex_o+apex_oo;
  139. x3r+apex_corr=x1r; alpha=diag_ratio(1,diag_stem,y3-y4l,x3r-x4l);
  140. penpos3(alpha*diag_stem,0); penpos4(alpha*diag_stem,0);
  141. x0=x1l; z0=whatever[z3r,z4r];
  142. x5'=x5; z5''=z5'+penoffset z4-z3 of currentpen=whatever[z4l,z3l];
  143. fill diag_end(2r,1r,1,.5,3l,4l)---z5''...lft z5'
  144.  ---lft z5l -- (x4r,y5l) -- z4r
  145.  if y0<h-cut:{z3r-z4r}...{up}(x1l-1,h-cut)
  146.   --(x1l,h-cut) else: -- z0 fi
  147.  --z2l--z2r--cycle;  % diagonal and upper stem
  148. filldraw stroke z5e--z6e;  % bar
  149. pickup tiny.nib; pos7(light_stem,0); rt x7r=x1r; bot y7=0;
  150. pos2'(light_stem,0); x2'=x7;
  151. filldraw stroke z2'e--z7e;  % lower stem
  152. if serifs: dish_serif(7,2',a,1/3,1.75u,
  153.   b,1/3,min(1.75u,w-.5u-rt x7r)); fi  % serif
  154. penlabels(0,1,2,3,4,5,6,7); endchar;
  155.  
  156. ecchar "The numeral 5";
  157. beginchar("5",9u#,fig_height#,0);
  158. italcorr fig_height#*slant-.5u#;
  159. adjust_fit(0,0);
  160. numeric bot_thickness,light_hair;
  161. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  162. light_hair=hround(cap_hair if hefty: -\\2stem_corr fi);
  163. pickup tiny.nib; pos5(vair,180); pos6(vair,90);
  164. bot y5=vround(.53h-vair); top y6r=max(vround .61803h+o,top y6r+y5+eps-y6l);
  165. pos3(light_hair,0); pos4(light_hair,0);
  166. lft x3l=max(1.35u,2.1u-.5light_hair); x3=x4=x5; y4=y5;
  167. top y3=h if not hefty: +\\o fi;
  168. filldraw stroke z3e--z4e;  % thin stem
  169. penpos7(cap_stem-fine,0); penpos8(bot_thickness-fine,-90);
  170. fine.rt x7r=hround(w-.9u); x8=.5[u,x7]; x6=.5[x5,x7];
  171. erase fill z5--bot z5--(x6,bot y5)--z6{left}
  172.  ..tension .9 and 1..{x5-x6,3(y5-y6)}cycle; % erase excess in middle
  173. filldraw stroke z6e{left}..tension .9 and 1..{x5-x6,3(y5-y6)}z5e;  % link
  174. pickup fine.nib; pos6'(vair,90); z6'=z6;
  175. y7=.5[y6,y8]; bot y8r=-o;
  176. filldraw stroke pulled_arc.e(6',7) & pulled_arc.e(7,8);  % bowl
  177. if serifs: pos9(hair,-180); y9=.5y5; lft x9r=hround .9u;
  178.  pos10(flare+1/3(cap_stem-stem),-180); bulb(8,9,10);  % bulb
  179. else: pos9(3/7[bot_thickness,flare],angle(-7u,-h));
  180.  lft x9r=hround(tiny.lft x3l-.75u); bot y9r=vround .15h-o;
  181.  x9l:=good.x x9l; y9l:=good.y y9l;
  182.  filldraw stroke term.e(8,9,left,1,4); fi  % terminal
  183. if hefty: pickup crisp.nib; pos1(slab,90); pos2(hair,0);
  184.  top y1r=h; x1=x4; rt x2r=hround(w-1.5u); y2=y1l-eps;
  185.  arm(1,2,a,0,0);  % arm
  186. else: numeric flag_breadth; flag_breadth=7/8[vair,cap_curve];
  187.  pos1(flag_breadth,90); pos2(flag_breadth,60);
  188.  pos0(vair,90); top y1r=tiny.top y3; top y2r=vround .95h+o; y0r=y1r;
  189.  lft x1=tiny.lft x3l; x2r=.5[x1,x0]; rt x0=hround(w-1.6u);
  190.  erase fill top z1r--z1r...{right}z2r
  191.   --(x2r,top y1r)--cycle; % erase excess at top
  192.  filldraw stroke z1e...{right}z2e...z0e; fi  % flag
  193. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  194.  
  195. ecchar "The numeral 6";
  196. beginchar("6",9u#,fig_height#,0);
  197. italcorr fig_height#*slant-.5u#;
  198. adjust_fit(0,0);
  199. numeric top_thickness,bot_thickness,side_thickness,pull;
  200. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  201. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  202. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  203. pull=min(.25,1.5superpull);
  204. pickup fine.nib; pos2(top_thickness,-270);
  205. pos3(side_thickness,-180); pos4(bot_thickness,-90);
  206. pos5(side_thickness,0); pos6(vair,90);
  207. lft x3r=w-rt x5r=hround max(.75u,1.5u-.5side_thickness);
  208. x4=x6-.1u=x2-u=.5w;
  209. top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
  210. y5=.5[y4,y6]; top y6=vround 5/8h+o;
  211. path p; p=pulled_super_arc.l(3,4)(pull);
  212. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  213. pos7(thin_join,180); z7l=point t of p;
  214. (x,y6r)=whatever[z7l,z6l]; x6r:=min(x,.5[x5r,x6]);
  215. filldraw stroke pulled_super_arc.e(2,3)(pull)
  216.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  217.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  218.  & z6e{left}...{direction t of p}z7e;  % arc and bowl
  219. if serifs: pos1(hair,-360); pos0(flare,-360);
  220.  rt x0r=max(rt x2+eps,hround(w-1.2u));
  221.  y0=vround min(.9h-.5flare,.85h+.5flare)+o;
  222.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  223. else: pos1(vround .1[top_thickness,flare],90);
  224.  top y1r=vround .97h+o; rt x1=hround(x5-.5);
  225.  filldraw stroke term.e(2,1,right,.9,4); fi  % terminal
  226. penlabels(0,1,2,3,4,5,6,7); endchar;
  227.  
  228. ecchar "The numeral 7";
  229. beginchar("7",9u#,fig_height#,0);
  230. italcorr fig_height#*slant-.5u#;
  231. adjust_fit(0,0);
  232. numeric arm_thickness, bot_width, top_shift, top_hair;
  233. if hefty: arm_thickness=Vround(slab+2stem_corr); top_shift=0;
  234.  bot_width=hround .51[curve,cap_curve]; top_hair=.4[thin_join,bot_width];
  235. else: arm_thickness=Vround .4[stem,cap_stem]; top_shift=.5u;
  236.  bot_width=flare; top_hair=cap_hair; fi
  237. if top_hair<tiny.breadth: top_hair:=tiny.breadth; fi
  238. pickup crisp.nib; pos2(arm_thickness,90); pos1(hair,180);
  239. top y2r=h; rt x2=hround(w-.75u+top_shift);
  240. lft x1r=hround(.75u+.5top_shift); y1=good.y(y2l-beak/2)-eps;
  241. arm(2,1,a,.3beak_darkness,-beak_jut);  % arm and beak
  242. pos3(hair,180); y3=good.y(y2r+beak/6)+eps; z3r=whatever[z1r,z.a0];
  243. penpos2'(eps,-90); z2'=z2r;
  244. arm(2',3,b,beak_darkness,x3r-x.a0);  % upward extension of beak
  245. pickup tiny.nib; pos4(top_hair,0); pos6(bot_width,0);
  246. bot y4=max(h-arm_thickness,h-slab,bot y2l); rt x4r=crisp.rt x2;
  247. lft x6l=hround(3.5u+top_shift-.5bot_width);
  248. if serifs: y6-.5bot_width=-o; filldraw z6l{down}..{up}z6r--cycle;  % bulb
  249. else: bot y6=-oo; fi
  250. if hefty: erase fill rt z4r--z4r...{down}z6r
  251.   --(rt x4r,y6)--cycle;  % erase excess at top
  252.  filldraw stroke z4e...{down}z6e;  % stroke
  253. else: pos5(top_hair,0); y5=2/3h; z5=whatever[z4,(.75u,y6)];
  254.  erase fill rt z4r--z4r--z5r--(rt x4r,y5)--cycle;  % erase excess at top
  255.  filldraw stroke z4e---z5e...{down}z6e; fi  % stroke
  256. penlabels(1,2,3,4,5,6); endchar;
  257.  
  258. ecchar "The numeral 8";
  259. beginchar("8",9u#,fig_height#,0);
  260. italcorr fig_height#*slant-.5u#;
  261. adjust_fit(0,0);
  262. numeric top_thickness,mid_thickness,bot_thickness,upper_side,lower_side,theta;
  263. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  264. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  265. x0=.5w; y0=.54h;
  266. if hefty: mid_thickness=vround 2/3vair; upper_side=hround(stem-3stem_corr);
  267.  lower_side=hround min(.5[curve,cap_curve]-stem_corr,upper_side+.25u);
  268.  penpos1(top_thickness,90); penpos2(upper_side,180);
  269.  penpos3(mid_thickness,270); penpos8(upper_side,360);
  270.  penpos4(mid_thickness,90); penpos7(lower_side,180);
  271.  penpos6(bot_thickness,270); penpos5(lower_side,360);
  272.  penpos0(vair,90); z3l=z0r; z4l=z0l;
  273.  x1=x6=.5w; x2r=w-x8r=hround u; x7r=w-x5r=hround .75u;
  274.  top y1r=h+o; bot y6r=-o; y2=y8=.5[y1l,y3l]; y7=y5=.5[y4l,y6l];
  275.  filldraw stroke pulled_arc.e(1,2)
  276.   & pulled_arc.e(2,3);  % left half of upper bowl
  277.  filldraw stroke pulled_arc.e(4,5)
  278.   & pulled_arc.e(5,6);  % right half of lower bowl
  279.  filldraw stroke pulled_arc.e(6,7)
  280.   & pulled_arc.e(7,4);  % left half of lower bowl
  281.  filldraw stroke pulled_arc.e(3,8)
  282.   & pulled_arc.e(8,1);  % right half of upper bowl
  283. else: pickup fine.nib; theta=90-angle(18u,h); slope:=-h/18u;
  284.  upper_side=max(fine.breadth,hround(.5[hair,stem]-stem_corr));
  285.  lower_side=hround(.5[hair,stem]+stem_corr);
  286.  if lower_side>1.2upper_side: upper_side:=lower_side; fi
  287.  pos1(top_thickness,-90); pos6(bot_thickness,-90);
  288.  x1=x6=.5w; top y1l=h+o; bot y6r=-o; pos0(cap_stem,theta);
  289.  lft x2l=w-rt x8l=hround 1.25u; lft x7r=w-rt x5r=hround .75u;
  290.  x2r-x2l=upper_side-fine; x5r-x5l=lower_side-fine;
  291.  ellipse_set(1l,2l,3l,0l); ellipse_set(1r,2r,3r,0r);
  292.  ellipse_set(6l,5l,4l,0l); ellipse_set(6r,5r,4r,0r);
  293.  numeric tau; tau=max(.8,.20710678/(superness-.5));
  294.  filldraw stroke z1e{left}..tension atleast tau..z2e{down}
  295.   ..z3e---z4e..z5e{down}..tension atleast tau..z6e{left};  % S stroke
  296.  pos7(lower_side,180); pos8(upper_side,180);
  297.  y7=.5[y5l,y5r]; y8=.5[y2l,y2r]; pos9(vair,90); z9=z0;
  298.  filldraw stroke z1e{right}..tension atleast tau..z8e{down}
  299.   ..tension atleast tau and atleast 1..{-18u,-.618h}z9e; % upper right stroke
  300.  filldraw stroke z6e{left}..tension atleast tau..z7e{up}
  301.   ..tension atleast tau and atleast 1..{18u,.5h}z9e; fi % lower left stroke
  302. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  303.  
  304. ecchar "The numeral 9";
  305. beginchar("9",9u#,fig_height#,0);
  306. italcorr fig_height#*slant-.5u#;
  307. adjust_fit(0,0);
  308. numeric top_thickness,bot_thickness,side_thickness,pull;
  309. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  310. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  311. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  312. pull=min(.25,1.5superpull);
  313. pickup fine.nib; pos2(bot_thickness,-90);
  314. pos3(side_thickness,0); pos4(top_thickness,90);
  315. pos5(side_thickness,180); pos6(vair,270);
  316. w-rt x3r=lft x5r=hround max(.75u,1.5u-.5side_thickness);
  317. x4-.1u=x6+.1u=x2+.75u=.5w;
  318. bot y2r=-o; y3=.5[y2,y4]; top y4r=h+o;
  319. y5=.5[y4,y6]; bot y6=vround 3/8h-o;
  320. path p; p=pulled_super_arc.l(3,4)(pull);
  321. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  322. pos7(thin_join,360); z7l=point t of p;
  323. (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
  324. filldraw stroke pulled_super_arc.e(2,3)(pull)
  325.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  326.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  327.  & z6e{right}...{direction t of p}z7e;  % arc and bowl
  328. if serifs: pos1(hair,-180); pos0(flare,-180);
  329.  lft x0r=min(lft x2-eps,hround 1.2u);
  330.  y0=vround max(.1h+.5flare,.15h-.5flare)-o;
  331.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  332. else: pos1(.1[bot_thickness,flare],-120);
  333.  bot y1r=vround .07h-o; lft x1r=hround 1.3u;
  334.  filldraw stroke term.e(2,1,left,.9,4); fi  % terminal
  335. penlabels(0,1,2,3,4,5,6,7); endchar;
  336.  
  337. endinput;
  338.